Option Explicit
' *********************************************************************** '
' *  Event Reminder							* '
' *					- Scott Crevier, 03-Dec-2000	* '
' *********************************************************************** '
Sub main()
	' *************************************************************** '
	' *  Declare variables.						* '
	' *************************************************************** '
	Dim vToday, vNow, vYYYY, vMM, vDD, vH, vM, vS
	Dim vEventFile, vFso, f
	Dim vArray, vLine
	Dim vWeekDays, vMonths, vWeekDay, vMonth
	Dim vSep, vRegExp, vMsg

	' *************************************************************** '
	' *  Initialize some variable values.				* '
	' *************************************************************** '
	vEventFile	= hs.GetScriptPath & "eventlist.txt"
	Set vFso	= CreateObject("Scripting.FileSystemObject")
	vSep		= Chr(9)

	vWeekDays	= Array("","Sun","Mon","Tue","Wed","Thu","Fri","Sat")
	vMonths		= Array("","Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

	' *************************************************************** '
	' *  Initialize some date variables.				* '
	' *************************************************************** '
	vNow		= Now
	Set vRegExp	= New RegExp
	vRegExp.Pattern	= "^(\d)$"

	vWeekDay	= vWeekDays(Weekday(vNow))
	vMonth		= vMonths(Month(vNow))
	vYYYY		= Year(vNow)
	vMM		= vRegExp.Replace(Month(vNow),"0$1")
	vDD		= vRegExp.Replace(Day(vNow),"0$1")
	vToday		= vYYYY & "-" & vMM & "-" & vDD

	' *************************************************************** '
	' *  Make sure the events file exists.				* '
	' *************************************************************** '
	If vFso.FileExists(vEventFile) = false Then
		hs.WriteLog	"Event Reminder", "Could not open event file (" & vEventFile & ")"
		Exit Sub
	End If

	' *************************************************************** '
	' *  Open the events file. Loop through the lines, finding all	* '
	' *  events with today's date.					* '
	' *************************************************************** '
	Set f = vFso.openTextFile(vEventFile, 1)
	Do While f.atEndOfStream = false
		vLine	= f.ReadLine
		vArray	= Split(vLine,vSep,2,1)

		If vArray(0) = vToday Then
			vMsg	= vMsg & vArray(1) & vbCr
		End If
	Loop
	f.Close

	' *************************************************************** '
	' *  Display the message.					* '
	' *************************************************************** '
	If vMsg <> "" Then
		MsgBox vMsg, 64, vWeekDay & ", " & vDD & "-" & vMonth & "-" & vYYYY
	Else
		hs.Speak "No events for today."
		MsgBox vToday
	End If
End Sub


' *********************************************************************** '
' *				End.					* '
' *********************************************************************** '